批处理全盘搜索指定文件获取其完整路径代码,Shell代码库,德仔网

代码语言

代码分类

【Shell】批处理全盘搜索指定文件获取其完整路径

作者:Batcher / 发布于2014/1/21/ 892

【方案一】for /f + dir

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%a:\nul (
    for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (
      if /i "%%~nxb" equ "%FileName%" (
        echo.%%b
      )
    )
  )
)
pause





【方案二】for /r（比 for /f + dir 效率高，但不会遍历隐藏文件）



@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%a:\nul (
    pushd %%a:\
    for /r %%b in ("*%FileName%") do (
      if /i "%%~nxb" equ "%FileName%" (
        echo.%%b
      )
    )
    popd
  )
)
pause



【方案三】WMIC（Win2000/WinXP HOME版、WinXP 精简版可能不支持）

@echo off
rem 指定待搜索的文件
set "FileName=test 1.bat"
echo 正在搜索，请稍候...
for %%a in ("%FileName%") do (
  set "nName=%%~na"
  set "xName=%%~xa"
)
set "xName=%xName:~1%"
for /f "skip=1 delims=" %%a in ('wmic datafile where "filename='%nName%' and Extension='%xName%'" get name') do (
  echo.%%a
)
pause

试试其它关键字

　全盘搜索　

同语言下

可能有用的

Batcher贡献的其它代码(5)