生成固定格式的业务编号代码,MSSQL代码库,德仔网

代码语言

代码分类

【MSSQL】生成固定格式的业务编号

作者:大卫 / 发布于2017/11/20/ 1320

ALTER PROCEDURE USP_GenerateCustomCode
(
	@bizFixStarting VARCHAR(20)		--固定业务开头字符
	,@tableName VARCHAR(200)		--指定要生成编号的表名称
	,@columnName VARCHAR(200)		--要生成编号的列名称
	,@seqNoSize INT=4				--顺序号长度
	,@bizCode VARCHAR(100) OUTPUT	--生成编号信息	
)
AS
BEGIN
	SET @bizCode=''
	IF ISNULL(@bizFixStarting,'')=''
	BEGIN
		RAISERROR('@bizFixStarting is empty',16,1)
		RETURN
	END
	IF ISNULL(@tableName,'')=''
	BEGIN
		RAISERROR('@tableName is empty',16,1)
		RETURN
	END
	IF ISNULL(@columnName,'')=''
	BEGIN
		RAISERROR('@columnName is empty',16,1)
		RETURN
	END
	
	--获取当前年月日(yymmdd,2016-5-27=160527)
	DECLARE @curYMD VARCHAR(6)=CONVERT(VARCHAR(10),GETDATE(),12)
	
	--当前将要生成扣款单号前缀
	DECLARE @curPrefix VARCHAR(10) =@bizFixStarting+@curYMD	
				
	--顺序号
	DECLARE @seqNo VARCHAR(100)
	DECLARE @maxSeqNo INT
	
	DECLARE @query NVARCHAR(MAX)
	SET @query=
		'SELECT @maxSeqNo='
		+' MAX(CAST(REPLACE('+@columnName+','''+@curPrefix+''','''') AS INT))'
		+' FROM '+@tableName
		+' WHERE LEFT('+@columnName+','+CAST(LEN(@bizFixStarting)+LEN('yymmdd') AS VARCHAR(30))+')='''+@curPrefix+''''
	EXEC sp_executesql  @query,N'@maxSeqNo int out',@maxSeqNo OUT
	IF(@@ERROR<>0)
	BEGIN
		RETURN
	END	
	
	--生成新顺序号要加1 
	SET @maxSeqNo=ISNULL(@maxSeqNo,0)+1                                   
	--生成固定位数，以0填充的顺序号
	SET @seqNo=RIGHT(REPLICATE('0',@seqNoSize)+CAST(@maxSeqNo AS VARCHAR(10)),@seqNoSize) 
	
	SET @bizCode=@curPrefix+@seqNo
END

试试其它关键字

同语言下

可能有用的

大卫贡献的其它代码(18)